[elinks-dev] [PATCH] Add support for nss_compat_ossl library (OpenSSL replacement).

Kalle Olavi Niemitalo kon at iki.fi
Sat Sep 6 17:27:16 PDT 2008

Kamil Dudka <kdudka at redhat.com> writes:

> +AC_ARG_WITH(nss_compat_ossl, AC_HELP_STRING([--with-nss_compat_ossl[=DIR]],
> +	    [NSS compatibility SSL libraries/include files]))

I'm getting this in configure:

                          NSS compatibility SSL libraries/include files

So apparently there aren't enough brackets.  I think you should
add a pair around the whole AC_HELP_STRING call.

The same bug is in some preexisting options too.  If you want to
fix those, please post a separate patch.

> +if test "$with_nss_compat_ossl" != "no"; then
> +	if test -z "$with_nss_compat_ossl"; then
> +		if pkg-config nss; then
> +			CFLAGS="$CFLAGS_X `pkg-config --cflags nss`"
> +			LIBS="$LIBS_X `pkg-config --libs nss`"
> +		else
> +			with_nss_compat_ossl=no
> +		fi
> +	else
> +		# Without pkg-config, we'll kludge in some defaults
> +		CFLAGS="$CFLAGS_X -I$with_nss_compat_ossl/include -I/usr/include/nss3 -I/usr/include/nspr4"
> +		LIBS="$LIBS_X -L$with_nss_compat_ossl/lib -lssl3 -lsmime3 -lnss3 -lplds4 -lplc4 -lnspr4 -lpthread -ldl"
> +	fi

Autoconf considers --with-nss_compat_ossl equivalent to
--with-nss_compat_ossl=yes.  Your code seems to treat that
"yes" as a directory name and skip pkg-config.

> +	# TODO: Mark this as non-warning when it becomes stable
> +	AC_MSG_WARN([Using nss_compat_ossl library for SSL.])

Because you don't consider the nss_compat_ossl support stable,
I think the configure script should select it only if the user
explicitly requests it or no other SSL library is available.
-------------- next part --------------
A non-text attachment was scrubbed...
Name: not available
Type: application/pgp-signature
Size: 188 bytes
Desc: not available
URL: <http://lists.linuxfromscratch.org/pipermail/elinks-dev/attachments/20080907/f3c42d12/attachment.sig>

More information about the elinks-dev mailing list